How to combine (join/merge) multiple .efu file lists?

If you are experiencing problems with "Everything", post here for assistance.
Post Reply
SuperDude
Posts: 96
Joined: Thu Sep 25, 2014 7:57 pm

How to combine (join/merge) multiple .efu file lists?

Post by SuperDude » Fri Dec 28, 2018 8:28 pm

I would like to create individual .efu file lists for cataloging CDs and DVDs, then combine all of the individual .efu file lists into a single .efu “master” file, so I can open the “master” .efu file and search through all of the CDs and DVDs at once. How would I go about doing this, please? Thank you!

vanisk
Posts: 150
Joined: Sat Oct 27, 2018 11:33 am

Re: How to combine (join/merge) multiple .efu file lists?

Post by vanisk » Fri Dec 28, 2018 9:10 pm

EFU files are comma-separated values (CSV) files which can be opened in text editors (Can also be opened in Spreadsheet).
We can just open the first file, append the contents of other efu files and store it in a single EFU file.

(or)
Place all the EFU files in a single folder, Within Command Prompt (cmd), CD to the efu file list location and run

Code: Select all

Copy *.efu final.efu
Last edited by vanisk on Fri Dec 28, 2018 10:30 pm, edited 1 time in total.

SuperDude
Posts: 96
Joined: Thu Sep 25, 2014 7:57 pm

Re: How to combine (join/merge) multiple .efu file lists?

Post by SuperDude » Fri Dec 28, 2018 10:29 pm

@vanisk: Thank you!

NotNull
Posts: 1465
Joined: Wed May 24, 2017 9:22 pm

Re: How to combine (join/merge) multiple .efu file lists?

Post by NotNull » Tue Jan 01, 2019 8:45 pm

SuperDude wrote:
Fri Dec 28, 2018 8:28 pm
“master” .efu file
Is @vanisk's solution good enough for you?
( I might have an alternative, but that requires writing some code and if you don't need it, that would be futile )

NotNull
Posts: 1465
Joined: Wed May 24, 2017 9:22 pm

Re: How to combine (join/merge) multiple .efu file lists?

Post by NotNull » Wed Jan 02, 2019 2:33 pm

Well, I wrote it anyway ;) as I realized that it would take me more time to descrie it than to build it ..

If you want to try this:
  • Put your .EFU files together in a folder
  • Add MasterEFU.cmd to this folder
  • Change the path to your Everything.exe in the script
    (currently: c:\program files\everything\everything.exe)
  • Run MasterEFU.cmd (for example by double-clicking it in File Explorer
Using some dummy data, this results in:
2019-01-02 15_15_54-Everything (MasterEFU).png
Now you can tell on which disk the file is that you were looking for...


Notes
- Everytime the script starts, it will load all .EFU files in it's folder. So you can add/remove EFU's and those will be loaded the next time you start MasterEFU.
- If you still want your combined list, you can do a Menu:File > Export > Save as EFU


MasterEFU.cmd

Code: Select all

@echo off
setlocal ENABLEDELAYEDEXPANSION

::_______________________________________________
::
::	SETTINGS
::_______________________________________________
::

	set EXE=c:\program files\everything\everything.exe
	rem set EFUPATH=c:\tools\everything\_park
	set EFUPATH=.



::_______________________________________________
::
::	INIT
::_______________________________________________
::

	pushd "%~dp0"
	set INI=%~n0.ini

	
::_______________________________________________
::
::	ACTION!
::_______________________________________________
::
	
	if not exist "%INI%" call :NEWINI

:: PREPARE INI
	set LIST=
	for %%x in (%EFUPATH%\*.efu) Do set LIST=!LIST!,"%%~fx"
	set LIST=%LIST:\=\\%
	echo filelists=%LIST%
	echo filelists=%LIST%>> "%INI%"

:: Start Everything
	start "" "%EXE%" -nodb -instance MasterEFU -config "%INI%"
   

goto :EOF



:NEWINI
(
	echo [Everything]
	echo allow_http_server=0
	echo allow_etp_server=0

	echo run_as_admin=0
	echo run_in_background=0
	echo show_in_taskbar=1
	echo show_tray_icon=0
	echo minimize_to_tray=0
	echo hide_on_close=0

	echo check_for_updates_on_startup=0

	echo auto_include_fixed_volumes=0
	echo auto_include_removable_volumes=0
	echo auto_include_fixed_refs_volumes=1
	echo auto_include_removable_refs_volumes=0

	echo file_list_filename_column_visible=1
) > "%INI%"

goto :EOF

You do not have the required permissions to view the files attached to this post.

SuperDude
Posts: 96
Joined: Thu Sep 25, 2014 7:57 pm

Re: How to combine (join/merge) multiple .efu file lists?

Post by SuperDude » Wed Jan 02, 2019 4:03 pm

Thank you very much!

NotNull
Posts: 1465
Joined: Wed May 24, 2017 9:22 pm

Re: How to combine (join/merge) multiple .efu file lists?

Post by NotNull » Wed Jan 02, 2019 9:18 pm

You're welcome! :)

Post Reply